Arduino com Ethernet Shield lendo Twitter

Hoje surgiu a oportunidade de utilizar o Ethernet Shield com chip Wiznet W5100 e slot de cartão SD que comprei no dealextreme:

Esse shield em particular te abre uma gama muito grande de projetos, te da a liberdade de acessar a internet e utilizar o cartão SD dele para fazer logs e tudo mais, não vou entrar muito nos detalhes dele, num post futuro quem sabe. No Brasil esse mesmo shield chega a custar entre 250-350 reais, então vale a pena esperar 1 mês e receber da China com preço de 17 USD.

Eu comprei ele mas nunca fiz muitos testes, mas hoje apareceu uma ideia que pode ser muito útil.É o seguinte, eu acesso um computador remotamente para fazer algumas atualizações, esse computador fica ligado 24/7, nunca é desligado.Como nenhum sistema é perfeito, é comum o computador travar e eu perder o acesso remotamente, impossibilitando de executar as ações já que o LogMeIn não consegue ligar ele a distancia.

Hoje esse computador travou, e a única solução até então é ir pessoalmente e reiniciar ele, foi ai que eu tive a ideia de utilizar o Arduino+Ethernet+Twitter.

O Ethenet shield acessa a internet,mais precisamente o servidor do twitter e a minha conta e faz a leitura da ultima coisa que eu postei, depois de fazer essa leitura, o Arduino checa se ela se encaixa em alguma ação pre determinada nele. Essa faixa de código determina isso:

Foi feito um exemplo com um LED, que pode ser substituído por um relé ou qualquer outro componente para controlar qualquer tipo de carga remotamente.

Sendo assim você pode ligar e desligar o comutador, cortando a energia dele, ou internamente conectando ao botão de reset.

O programa esta muito bem comentado, e fácil de compreender, o tempo de refrescamento esta em 20000 milissegundos, ou seja, 20 segundos, e pode ser alterado para ter resposta mais rápido, mas achei melhor deixar 20 segundos para não sobrecarregar.

Código Completo:

/*

  Twitter Client

 Esse sketch conecta ao Twitter usando um Ethernet shield. Ele vasculha o XML

 retornado, e procura por <text>esse é um tweet</text>

 Circuito:

 * Ethernet shield ligado nos pinos 10, 11, 12, 13

por Vinicius R.

VRO Projetos

viniciusro@gmail.com

 Esse codigo é de dominio publico.

 */

#include <SPI.h>

#include <Ethernet.h>

const int led = 7;

// entre com MAC e IP para seu controlador.

// O IP vai depender da sua rede:

byte mac[] = {0x00, 0xAA, 0xBB, 0xCC, 0xDE, 0x01};

IPAddress ip(192,168,1,20);

// inicia a biblioteca:

EthernetClient client;

const unsigned long requestInterval = 20000;  // delay entre pedidos

char serverName[] = "api.twitter.com";  // pagina do twitter URL

boolean requested;                   // se vc fez um pedido des de quando conectou

unsigned long lastAttemptTime = 0;            // ultima vez que vc estava conectado em milesegundos

String currentLine = "";            // string para guardar texto de servidor

String tweet = "";                  // string para guardar o tweet

boolean readingTweet = false;       // se vc está atualmente lendo o tweet

void setup() 

{

  pinMode(led, OUTPUT);

  // reserva espaço para as strings:

  currentLine.reserve(256);

  tweet.reserve(150);

 // abre comunicação serial e espera a porta abrir:

  Serial.begin(9600);

  // tenta conexão DHCP:

  Serial.println("Tentando pegar um IP usando DHCP:");

  if (!Ethernet.begin(mac)) 

  {

    // se o  DHCP falhar, começa tentar manualmente:

    Serial.println("não foi possivel pegar um IP usando DHCP, tentando manualmente");

    Ethernet.begin(mac, ip);

  }

  Serial.print("Meu IP:");

  Serial.println(Ethernet.localIP());

  // Conecta no Twitter:

  connectToServer();

}

void loop()

{

  if (client.connected()) 

  {

    if (client.available()) 

    {

      // ler os bytes de entrada:

      char inChar = client.read();

      // adiciona os bytes de entrada ao final da linha:

      currentLine += inChar; 

      // se vc receber "newline" nova linha, limpa a linha:

      if (inChar == '\n') 

      {

        currentLine = "";

      } 

      // se a linha atual terminar com <text>, vai ser seguida do tweet:

      if ( currentLine.endsWith("<text>")) 

      {

        // o tweet esta começando. Limpa a string tweet:

        readingTweet = true; 

        tweet = "";

      }

      // se vc esta atualmente lendo os bytes do tweet, adicona eles a String do tweet,

      if (readingTweet) 

      {

        if (inChar != '<') 

        {

          tweet += inChar;

        } 

        else 

          {

          // se vc receber um caracter "<", chegou ao final do tweet:

          readingTweet = false;

          Serial.println(tweet);

            if(tweet==">.215 ligado")

             {

              digitalWrite(led, HIGH);

              Serial.println("Computador .215 LIGADO");

             }   

            if(tweet==">.215 desligado")

             {

              digitalWrite(led, LOW);

              Serial.println("Computador .215 DESLIGADO");

             }   

            if(tweet==">status")

             {

              Serial.print("Computador .215 esta: ");

              int estado = digitalRead(led);

              if (estado==1)

                {

                 Serial.print("Ligado ");

                }

              if (estado==0)

                {

                 Serial.print("Desligado ");

                }

              Serial.println(estado);

             }

          // fecha conexão com servidor:

          client.stop(); 

        }

      }

    }   

  }

  else if (millis() - lastAttemptTime > requestInterval) 

  {

    // se vc não esta conectado, e passou 2 minutos des da sua ultima conexão

    // então tenta reconectar:

    connectToServer();

  }

}

void connectToServer() 

{

  // tenta conectar e espera em milesegundos:

  Serial.println("conectando no servidor...");

  if (client.connect(serverName, 80)) 

  {

    Serial.println("fazendo pedido de HTTP...");

    // faz pedido HTTP GET para o twitter:

    client.println("GET /1/statuses/user_timeline.xml?screen_name=viniciusrdo&count=1 HTTP/1.1");

    client.println("HOST: api.twitter.com");

    client.println();

  }

  // observa o tempo dessa tentativa de conexão:

  lastAttemptTime = millis();

}

Esse vídeo exemplifica seu funcionamento: